Hét vraag- en antwoordplatform van Nederland

Kun je een formule maken om direct het aantal 'doelpunten voor' te berekenen?

Ik wil graag het aantal doelpunten voor en doelpunten tegen berekenen van de verschillende landen (zie afbeelding). Ik dacht aan een formule als de volgende, maar die werkt niet:

=(SOM.ALS(C17:E46;$C17:$C46="België";E17:E46))+(SOM.ALS(F17:H46;$H17:$H46="België";F17:F46))

Weet iemand een mogelijke formule?

Verwijderde gebruiker
12 jaar geleden
Geef jouw antwoord
0 / 2500
Geef Antwoord

Het beste antwoord

Het onderstaande zou volgens mij ook moeten werken

=SOMPRODUCT(($C$17:$C$46=J17)*1;$D$17:$D$46)
+SOMPRODUCT(($F$17:$F$46=J17)*1;$E$17:$E$46)
Verwijderde gebruiker
12 jaar geleden

Andere antwoorden (1)

Zet in cel N17 de volgende formule:

    =SUM(($C$17:$C$46=$J17)*$D$17:$D$46+($F$17:$F$46=$J17)*$E$17:$E$46)

Heel belangrijk: type deze formule in, en als je klaar bent met typen moet je NIET op Enter drukken of met de muis ergens op klikken; in plaats daarvan moet je op Control-Shift-Enter drukken. Dit doe je dus DIRECT na het intypen van bovenstaande formule.

Je ziet nu dat Excel accolades om jouw formule heen zet. In plaats van bovenstaande formule zie je dus het volgende staan:

    {=SUM(($C$17:$C$46=$J17)*$D$17:$D$46+($F$17:$F$46=$J17)*$E$17:$E$46)}

Nu trek je deze formule door naar beneden, tot aan cel N22.
 

Toegevoegd na 16 minuten:
 
In het Engels heet dit soort formules (die je dus met Control-Shift Enter invoert): array formulas.

Het werkt als volgt.

--  De accolades geven aan dat de formule moet worden uitgevoerd voor elke cel in een range. Hier is de range: $C$17:$C$46 en $D$17:$D$46, en nog twee range:s $F$17:$F$46 en $E$17:$E$46.

--  De eerste cel in de range ($C$17 resp. $F$17) wordt vergeleken met $J17, zoals in de formule staat. Omdat er met het resultaat van die vergelijking wordt gerekend, komt er een 0 uit als de vergelijking onwaar is, en een 1 als de vergelijking waar is. $J17 is "België", dus als $C$17 "België" is komt er 1 uit, anders 0. Enzovoort voor de hele range $C$17:$C$46.

--  Je vermenigvuldigt die 0 of die 1 met het getal dat daarnaast staat, in dit geval in $D$17. Dus overal waar "België" in kolom C staat, vermenigvuldig je de waarde in kolom D met 1; overal waar iets anders in kolom C staat, vermenigvuldig je de waarde inkolom D met 0. Zo neem je alleen die waarden van kolom D mee die voor België gelden.

--  De accolades zorgen ervoor dat de resultaten van al die vermenigvuldigingen worden opgeteld.
 

Toegevoegd na 17 minuten:
 
Als je het principe van de array formulas eenmaal kent, kun je het ook in andere situaties toepassen.

Het leuke is dat bijna niemand dit begrijpt, dus je kunt er "geek points" mee scoren. ;-)
 

Toegevoegd na 20 minuten:
 
Oeps, ik zie dat ik mijn formule heb gegeven voor de engelstalige versie van Excel. Jij hebt de nederlandstalige versie; je zult dus in mijn formule SUM moeten veranderen in SOM; daarna zal het prima werken.
 
Cryofiel
12 jaar geleden
Deel jouw antwoord
0 / 2500
Geef Antwoord
logo van Kompas Publishing

GoeieVraag.nl is onderdeel van Kompas Publishing